diff --git a/pkgs/tools/misc/broadlink-cli/default.nix b/pkgs/tools/misc/broadlink-cli/default.nix
new file mode 100644
index 000000000000..2ba5499d7f77
--- /dev/null
+++ b/pkgs/tools/misc/broadlink-cli/default.nix
@@ -0,0 +1,37 @@
+{ stdenv, python2Packages, fetchFromGitHub }:
+
+python2Packages.buildPythonApplication rec {
+  pname = "broadlink-cli";
+  inherit (python2Packages.broadlink) version;
+
+  # the tools are available as part of the source distribution from GH but
+  # not pypi, so we have to fetch them here.
+  src = fetchFromGitHub {
+    owner  = "mjg59";
+    repo   = "python-broadlink";
+    # this rev is version 0.9
+    rev    = "766b7b00fb1cec868e3d5fca66f1aada208959ce";
+    sha256 = "0j0idzxmpwkb1lbgvi9df2hbxafm5hxjc6mgg5481lq7z4z1r4nb";
+  };
+
+  format = "other";
+
+  propagatedBuildInputs = with python2Packages; [
+    broadlink
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 -t $out/bin cli/broadlink_{cli,discovery}
+    install -Dm644 -t $out/share/doc/broadlink cli/README.md
+
+    runHook postInstall
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Tools for interfacing with Broadlink RM2/3 (Pro) remote controls, A1 sensor platforms and SP2/3 smartplugs";
+    maintainers = with maintainers; [ peterhoeg ];
+    inherit (python2Packages.broadlink.meta) homepage license;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 8905abe426aa..d95ef3723e25 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -237,6 +237,8 @@ in
 
   mod = callPackage ../development/tools/mod { };
 
+  broadlink-cli = callPackage ../tools/misc/broadlink-cli {};
+
   mht2htm = callPackage ../tools/misc/mht2htm { };
 
   fetchpatch = callPackage ../build-support/fetchpatch { };