diff --git a/pkgs/by-name/wi/wio/package.nix b/pkgs/by-name/wi/wio/package.nix
new file mode 100644
index 000000000000..73255a38208b
--- /dev/null
+++ b/pkgs/by-name/wi/wio/package.nix
@@ -0,0 +1,76 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, alacritty
+, cage
+, cairo
+, libxkbcommon
+, makeWrapper
+, mesa
+, meson
+, ninja
+, pkg-config
+, udev
+, unstableGitUpdater
+, wayland
+, wayland-protocols
+, wlroots
+, xwayland
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "wio";
+  version = "unstable-2023-05-28";
+
+  src = fetchFromGitHub {
+    owner = "Rubo3";
+    repo = "wio";
+    rev = "9d33d60839d3005ee16b5b04ae7f42c049939058";
+    hash = "sha256-ylJ8VHQU4TWLrhxGRo6HHOB7RWTVAThMQRw0uAFboNE=";
+  };
+
+  nativeBuildInputs = [
+    makeWrapper
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs = [
+    cairo
+    libxkbcommon
+    mesa
+    udev
+    wayland
+    wayland-protocols
+    wlroots
+    xwayland
+  ];
+
+  strictDeps = false; # why is it so hard?
+
+  env.NIX_CFLAGS_COMPILE = "-Wno-error=maybe-uninitialized";
+
+  postInstall = ''
+    wrapProgram $out/bin/wio \
+      --prefix PATH ":" "${lib.makeBinPath [ alacritty cage ]}"
+  '';
+
+  passthru = {
+    providedSessions = [ "wio" ];
+    updateScript = unstableGitUpdater { };
+  };
+
+  meta = {
+    homepage = "https://github.com/Rubo3/wio";
+    description = "Wayland compositor similar to Plan 9's rio";
+    longDescription = ''
+      Wio is a Wayland compositor for Linux and FreeBSD which has a similar look
+      and feel to plan9's rio.
+    '';
+    license = with lib.licenses; [ bsd3 ];
+    mainProgram = "wio";
+    maintainers = with lib.maintainers; [ AndersonTorres ];
+    inherit (wayland.meta) platforms;
+  };
+})
diff --git a/pkgs/top-level/aliases.nix b/pkgs/top-level/aliases.nix
index df1ee47a4f2f..e67c8ece527c 100644
--- a/pkgs/top-level/aliases.nix
+++ b/pkgs/top-level/aliases.nix
@@ -976,7 +976,6 @@ mapAliases ({
   ''; # Add 2023-07-29
   wcm = throw "'wcm' has been renamed to/replaced by 'wayfirePlugins.wcm'"; # Add 2023-07-29
   webkitgtk_5_0 = throw "'webkitgtk_5_0' has been superseded by 'webkitgtk_6_0'"; # Added 2023-02-25
-  wio = throw "wio has been removed from nixpkgs, it was unmaintained and required wlroots_0_14 at the time of removal"; # Added 2023-04-28
   wineWayland = wine-wayland;
   win-qemu = throw "'win-qemu' has been replaced by 'virtio-win'"; # Added 2023-08-16
   win-virtio = virtio-win; # Added 2023-10-17