mirror of
https://gitlab.kitware.com/vtk/vtk-m
synced 2024-07-06 07:17:25 +00:00
182 lines
7.2 KiB
CMake
182 lines
7.2 KiB
CMake
##============================================================================
|
|
## Copyright (c) Kitware, Inc.
|
|
## All rights reserved.
|
|
## See LICENSE.txt for details.
|
|
##
|
|
## This software is distributed WITHOUT ANY WARRANTY; without even
|
|
## the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
|
|
## PURPOSE. See the above copyright notice for more information.
|
|
##============================================================================
|
|
|
|
# When this file is run by CMake through the find_package command, the
|
|
# following targets will exist:
|
|
# vtkm::cont Target that contains most of VTK-m
|
|
#
|
|
# vtkm::rendering Target that contains all the rendering code
|
|
#
|
|
# vtkm::filter Target that contains all of VTK-m pre-built filters
|
|
#
|
|
# vtkm::source Target that contains all of VTK-m pre-built sources
|
|
#
|
|
# vtkm::tbb Target that contains tbb related link information
|
|
# implicitly linked to by `vtkm_cont` if tbb is enabled
|
|
#
|
|
# vtkm::openmp Target that contains openmp related link information
|
|
# implicitly linked to by `vtkm_cont` if openmp is enabled
|
|
#
|
|
# vtkm::cuda Target that contains cuda related link information
|
|
# implicitly linked to by `vtkm_cont` if cuda is enabled
|
|
#
|
|
# The following local variables will also be defined:
|
|
#
|
|
# VTKm_VERSION Holds the version string of "Major.Minor"
|
|
# VTKm_VERSION_FULL Holds the version string of "Major.Minor.Patch.GitSha1"
|
|
# VTKm_VERSION_MAJOR Holds just the major version number
|
|
# VTKm_VERSION_MINOR Holds just the minor version number
|
|
# VTKm_VERSION_PATCH Holds just the patch version number
|
|
#
|
|
# VTKm_BUILD_SHARED_LIBS Will be enabled if VTK-m was built shared/dynamic
|
|
# VTKm_ENABLE_CUDA Will be enabled if VTK-m was built with CUDA support
|
|
# VTKm_ENABLE_TBB Will be enabled if VTK-m was built with TBB support
|
|
# VTKm_ENABLE_OPENMP Will be enabled if VTK-m was built with OpenMP support
|
|
# VTKm_ENABLE_KOKKOS Will be enabled if VTK-m was built with Kokkos support
|
|
# VTKm_ENABLE_LOGGING Will be enabled if VTK-m was built with logging support
|
|
# VTKm_ENABLE_MPI Will be enabled if VTK-m was built with MPI support
|
|
# VTKm_ENABLE_RENDERING Will be enabled if VTK-m was built with rendering support
|
|
# VTKm_ENABLE_GL_CONTEXT Will be enabled if VTK-m rendering was built with a GL context
|
|
# VTKm_ENABLE_OSMESA_CONTEXT Will be enabled if VTK-m rendering was built with a osmesa context
|
|
# VTKm_ENABLE_EGL_CONTEXT Will be enabled if VTK-m rendering was built with a EGL context
|
|
#
|
|
|
|
if (CMAKE_VERSION VERSION_LESS "3.12")
|
|
message(FATAL_ERROR "VTK-m requires CMake 3.12+")
|
|
endif()
|
|
if("${CMAKE_GENERATOR}" MATCHES "Visual Studio" AND
|
|
CMAKE_VERSION VERSION_LESS "3.11")
|
|
message(FATAL_ERROR "VTK-m requires CMake 3.11+ when using the Visual Studio Generators")
|
|
endif()
|
|
|
|
@PACKAGE_INIT@
|
|
|
|
# The VTKm version number
|
|
set(VTKm_VERSION_MAJOR "@VTKm_VERSION_MAJOR@")
|
|
set(VTKm_VERSION_MINOR "@VTKm_VERSION_MINOR@")
|
|
set(VTKm_VERSION_PATCH "@VTKm_VERSION_PATCH@")
|
|
set(VTKm_VERSION_FULL "@VTKm_VERSION_FULL@")
|
|
set(VTKm_VERSION "@VTKm_VERSION@")
|
|
|
|
set(VTKm_BUILD_SHARED_LIBS "@VTKm_BUILD_SHARED_LIBS@")
|
|
set(VTKm_ENABLE_CUDA "@VTKm_ENABLE_CUDA@")
|
|
set(VTKm_ENABLE_KOKKOS "@VTKm_ENABLE_KOKKOS@")
|
|
set(VTKm_ENABLE_OPENMP "@VTKm_ENABLE_OPENMP@")
|
|
set(VTKm_ENABLE_TBB "@VTKm_ENABLE_TBB@")
|
|
set(VTKm_ENABLE_LOGGING "@VTKm_ENABLE_LOGGING@")
|
|
set(VTKm_ENABLE_RENDERING "@VTKm_ENABLE_RENDERING@")
|
|
set(VTKm_ENABLE_ANARI "@VTKm_ENABLE_ANARI@")
|
|
set(VTKm_ENABLE_GL_CONTEXT "@VTKm_ENABLE_GL_CONTEXT@")
|
|
set(VTKm_ENABLE_OSMESA_CONTEXT "@VTKm_ENABLE_OSMESA_CONTEXT@")
|
|
set(VTKm_ENABLE_EGL_CONTEXT "@VTKm_ENABLE_EGL_CONTEXT@")
|
|
set(VTKm_ENABLE_MPI "@VTKm_ENABLE_MPI@")
|
|
set(VTKm_ENABLE_TESTING_LIBRARY "@VTKm_ENABLE_TESTING_LIBRARY@")
|
|
set(VTKm_USE_DEFAULT_TYPES_FOR_ASCENT "@VTKm_USE_DEFAULT_TYPES_FOR_ASCENT@")
|
|
|
|
# This is true when the package is still in the build directory (not installed)
|
|
if(CMAKE_CURRENT_LIST_DIR STREQUAL "@VTKm_BUILD_CMAKE_BASE_DIR@/@VTKm_INSTALL_CONFIG_DIR@")
|
|
set(VTKm_PACKAGE_IN_BUILD TRUE)
|
|
endif()
|
|
|
|
if(VTKm_PACKAGE_IN_BUILD)
|
|
set_and_check(VTKm_CMAKE_MODULE_PATH "@VTKm_SOURCE_DIR@/CMake")
|
|
else()
|
|
set_and_check(VTKm_CMAKE_MODULE_PATH "@PACKAGE_VTKm_INSTALL_CMAKE_MODULE_DIR@")
|
|
endif()
|
|
|
|
include(CMakeFindDependencyMacro)
|
|
|
|
set(CMAKE_MODULE_PATH_save_vtkm "${CMAKE_MODULE_PATH}")
|
|
set(PACKAGE_PREFIX_DIR_save_vtkm "${PACKAGE_PREFIX_DIR}")
|
|
list(INSERT CMAKE_MODULE_PATH 0 "${CMAKE_CURRENT_LIST_DIR}")
|
|
|
|
if (VTKm_ENABLE_TBB)
|
|
find_dependency(TBB)
|
|
if (NOT TBB_FOUND)
|
|
set(VTKm_FOUND 0)
|
|
list(APPEND VTKm_NOT_FOUND_REASON "TBB not found: ${TBB_NOT_FOUND_MESSAGE}")
|
|
endif()
|
|
endif()
|
|
|
|
if (VTKm_ENABLE_OPENMP)
|
|
find_dependency(OpenMP)
|
|
if (NOT OpenMP_FOUND)
|
|
set(VTKm_FOUND 0)
|
|
list(APPEND VTKm_NOT_FOUND_REASON "OpenMP not found: ${OpenMP_NOT_FOUND_MESSAGE}")
|
|
endif()
|
|
endif()
|
|
|
|
if (VTKm_ENABLE_ANARI)
|
|
find_dependency(anari)
|
|
if (NOT anari_FOUND)
|
|
set(VTKm_FOUND 0)
|
|
list(APPEND VTKm_NOT_FOUND_REASON "ANARI not found: ${anari_NOT_FOUND_MESSAGE}")
|
|
endif()
|
|
endif()
|
|
|
|
set(PACKAGE_PREFIX_DIR ${PACKAGE_PREFIX_DIR_save_vtkm})
|
|
|
|
# Load the library exports, but only if not compiling VTK-m itself
|
|
set_and_check(VTKm_CONFIG_DIR "@PACKAGE_VTKm_INSTALL_CONFIG_DIR@")
|
|
set(VTKM_FROM_INSTALL_DIR FALSE)
|
|
if(NOT "${CMAKE_BINARY_DIR}" STREQUAL "@VTKm_BINARY_DIR@")
|
|
set(VTKM_FROM_INSTALL_DIR TRUE)
|
|
include(${VTKm_CONFIG_DIR}/VTKmTargets.cmake)
|
|
|
|
if(DEFINED PACKAGE_FIND_VERSION AND PACKAGE_FIND_VERSION VERSION_LESS 2.0)
|
|
add_library(vtkm_cont ALIAS vtkm::cont)
|
|
add_library(vtkm_filter ALIAS vtkm::filter)
|
|
add_library(vtkm_io ALIAS vtkm::io)
|
|
add_library(vtkm_rendering ALIAS vtkm::rendering)
|
|
add_library(vtkm_source ALIAS vtkm::source)
|
|
add_library(vtkm_worklet ALIAS vtkm::worklet)
|
|
endif()
|
|
endif()
|
|
|
|
# Once we can require CMake 3.15 for all cuda builds we can
|
|
# replace this with setting `cuda_architecture_flags` as part of the
|
|
# EXPORT_PROPERTIES of the vtkm::cuda target
|
|
if(VTKm_ENABLE_CUDA AND VTKM_FROM_INSTALL_DIR)
|
|
# Canonical way of setting CUDA arch
|
|
if(CMAKE_VERSION VERSION_GREATER_EQUAL 3.18)
|
|
set_target_properties(vtkm::cuda PROPERTIES CUDA_ARCHITECTURES "@CMAKE_CUDA_ARCHITECTURES@")
|
|
endif()
|
|
|
|
set_target_properties(vtkm::cuda PROPERTIES
|
|
# Legacy way of setting CUDA arch
|
|
cuda_architecture_flags "@VTKm_CUDA_Architecture_Flags@"
|
|
requires_static_builds TRUE)
|
|
|
|
# If VTK-m is built with 3.18+ and the consumer is < 3.18 we need to drop
|
|
# these properties as they break the VTK-m cuda flag logic
|
|
if(CMAKE_VERSION VERSION_LESS 3.18)
|
|
set_target_properties(vtkm::cuda PROPERTIES INTERFACE_LINK_OPTIONS "")
|
|
endif()
|
|
endif()
|
|
|
|
# VTKm requires some CMake Find modules not included with CMake, so
|
|
# include the CMake modules distributed with VTKm.
|
|
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH_save_vtkm} ${VTKm_CMAKE_MODULE_PATH})
|
|
unset(CMAKE_MODULE_PATH_save_vtkm)
|
|
|
|
if(VTKm_ENABLE_CUDA)
|
|
if (CMAKE_VERSION VERSION_LESS 3.13)
|
|
message(FATAL_ERROR "VTK-m with CUDA requires CMake 3.13+")
|
|
endif()
|
|
endif()
|
|
|
|
# This includes a host of functions used by VTK-m CMake.
|
|
include(VTKmWrappers)
|
|
include(VTKmRenderingContexts)
|
|
|
|
# Setup diy magic of chosing the appropriate mpi/no_mpi library to link against
|
|
include(VTKmDIYUtils)
|
|
vtkm_diy_init_target()
|