afew: rewrite expression

it's an application, not a python module

Also, remove name attribute.
Build with python 3 by default.

afew: make setuptools_scm a buildInput

afew: don't set SETUPTOOLS_SCM_PRETEND_VERSION anymore

we fetch from pypi, with version info properly set, so this shouldn't be
an issue.

afew: set license

afew: add notmuch binary to PATH

it seems afew calls "notmuch new" in MailMover.py

afew: don't set LD_LIBRARY_PATH

the library is already hardcoded pythonPackages.notmuch's globals.py

pkgs/applications/networking/mailreaders/afew/default.nix

@@ -0,0 +1,28 @@
+{ stdenv, pythonPackages, notmuch }:
+
+pythonPackages.buildPythonApplication rec {
+  pname = "afew";
+  version = "1.2.0";
+
+  src = pythonPackages.fetchPypi {
+    inherit pname version;
+    sha256 = "121w7bd53xyibllxxbfykjj76n81kn1vgjqd22izyh67y8qyyk5r";
+  };
+
+  buildInputs = with pythonPackages; [ setuptools_scm ];
+
+  propagatedBuildInputs = with pythonPackages; [
+    pythonPackages.notmuch chardet
+  ] ++ stdenv.lib.optional (!pythonPackages.isPy3k) subprocess32;
+
+  makeWrapperArgs = [
+    ''--prefix PATH ':' "${notmuch}/bin"''
+  ];
+
+  meta = with stdenv.lib; {
+    homepage = https://github.com/afewmail/afew;
+    description = "An initial tagging script for notmuch mail";
+    license = licenses.isc;
+    maintainers = with maintainers; [ garbas andir flokli ];
+  };
+}

pkgs/development/python-modules/afew/default.nix

@@ -1,34 +0,0 @@
-{ stdenv, buildPythonPackage, fetchFromGitHub
-, isPy3k , setuptools_scm, notmuch, chardet, subprocess32 }:
-
-buildPythonPackage rec {
-  pname = "afew";
-  version = "1.2.0";
-  name = "${pname}-${version}";
-
-  src = fetchFromGitHub {
-    owner = "afewmail";
-    repo = "afew";
-    rev = "3405475276a2433e1238be330e538ebf2a976e5e";
-    sha256 = "1h974avnfc6636az130yjqwm28z3aaqm49bjhpy3razx6zvyhzlf";
-  };
-
-  buildInputs = [ setuptools_scm ];
-  SETUPTOOLS_SCM_PRETEND_VERSION = "${version}";
-
-  propagatedBuildInputs = [
-    notmuch
-    chardet
-  ] ++ stdenv.lib.optional (!isPy3k) subprocess32;
-
-  postInstall = ''
-    wrapProgram $out/bin/afew \
-      --prefix LD_LIBRARY_PATH : ${notmuch}/lib
-  '';
-
-  meta = with stdenv.lib; {
-    homepage = https://github.com/afewmail/afew;
-    description = "An initial tagging script for notmuch mail";
-    maintainers = with maintainers; [ garbas andir flokli ];
-  };
-}

pkgs/top-level/all-packages.nix

@@ -414,6 +414,8 @@ with pkgs;
 
   aescrypt = callPackage ../tools/misc/aescrypt { };
 
+  afew = callPackage ../applications/networking/mailreaders/afew { pythonPackages = python3Packages; };
+
   afio = callPackage ../tools/archivers/afio { };
 
   afl = callPackage ../tools/security/afl {

pkgs/top-level/python-packages.nix

@@ -390,8 +390,6 @@ in {
 
   adal = callPackage ../development/python-modules/adal { };
 
-  afew = callPackage ../development/python-modules/afew { };
-
   aiodns = callPackage ../development/python-modules/aiodns { };
 
   aiofiles = callPackage ../development/python-modules/aiofiles { };