7e5f0cd4e9
https://github.com/DisplayLink/evdi/releases/tag/v1.6.2 Since it's short: support for 5.2 kernel Intel-IOMMU workaround workaround for problem with FourCC when switching Xorg <-> Wayland fix issues found with Coverity
35 lines
1.0 KiB
Nix
35 lines
1.0 KiB
Nix
{ stdenv, fetchFromGitHub, kernel, libdrm }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "evdi";
|
|
version = "1.6.2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "DisplayLink";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
sha256 = "0ajjsh1fw7w0k28r6qq7kh3qcr87gzzjp8s890algbglynlafzfw";
|
|
};
|
|
|
|
nativeBuildInputs = kernel.moduleBuildDependencies;
|
|
|
|
buildInputs = [ kernel libdrm ];
|
|
|
|
makeFlags = [ "KVER=${kernel.modDirVersion}" "KDIR=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build" ];
|
|
|
|
hardeningDisable = [ "format" "pic" "fortify" ];
|
|
|
|
installPhase = ''
|
|
install -Dm755 module/evdi.ko $out/lib/modules/${kernel.modDirVersion}/kernel/drivers/gpu/drm/evdi/evdi.ko
|
|
install -Dm755 library/libevdi.so $out/lib/libevdi.so
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Extensible Virtual Display Interface";
|
|
platforms = platforms.linux;
|
|
license = with licenses; [ lgpl21 gpl2 ];
|
|
homepage = https://www.displaylink.com/;
|
|
broken = versionOlder kernel.version "4.9" || versionAtLeast kernel.version "4.18" || stdenv.isAarch64;
|
|
};
|
|
}
|