4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
41 lines
1.2 KiB
Nix
41 lines
1.2 KiB
Nix
{ lib, stdenv, fetchFromGitHub, python3, libreoffice-unwrapped, asciidoc, makeWrapper
|
|
# whether to install odt2pdf/odt2doc/... symlinks to unoconv
|
|
, installSymlinks ? true
|
|
}:
|
|
|
|
# IMPORTANT: unoconv must use the same python version as libreoffice (unless it
|
|
# will not be able to load the pyuno module from libreoffice).
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "unoconv";
|
|
version = "0.9.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "unoconv";
|
|
repo = "unoconv";
|
|
rev = version;
|
|
sha256 = "1akx64686in8j8arl6vsgp2n3bv770q48pfv283c6fz6wf9p8fvr";
|
|
};
|
|
|
|
buildInputs = [ asciidoc makeWrapper ];
|
|
|
|
preBuild = ''
|
|
makeFlags=prefix="$out"
|
|
'';
|
|
|
|
postInstall = ''
|
|
sed -i "s|/usr/bin/env python.*|${python3}/bin/${python3.executable}|" "$out/bin/unoconv"
|
|
wrapProgram "$out/bin/unoconv" --set UNO_PATH "${libreoffice-unwrapped}/lib/libreoffice/program/"
|
|
'' + (if installSymlinks then ''
|
|
make install-links prefix="$out"
|
|
'' else "");
|
|
|
|
meta = with lib; {
|
|
description = "Convert between any document format supported by LibreOffice/OpenOffice";
|
|
homepage = "http://dag.wieers.com/home-made/unoconv/";
|
|
license = licenses.gpl2;
|
|
platforms = platforms.linux;
|
|
maintainers = [ maintainers.bjornfor ];
|
|
};
|
|
}
|