e1cb839d17
Also fix D-Bus config dir path: The configure script is appending `/dbus-1/system.d` so when we added passed in `$out/etc/dbus-1/system.d`, it ended up with extra nesting.
150 lines
3.8 KiB
Nix
150 lines
3.8 KiB
Nix
{ stdenv, fetchurl, fetchFromGitHub, wrapQtAppsHook, python3, python3Packages, zbar, secp256k1
|
|
, enableQt ? !stdenv.isDarwin
|
|
|
|
|
|
# for updater.nix
|
|
, writeScript
|
|
, common-updater-scripts
|
|
, bash
|
|
, coreutils
|
|
, curl
|
|
, gnugrep
|
|
, gnupg
|
|
, gnused
|
|
, nix
|
|
}:
|
|
|
|
let
|
|
version = "3.3.8";
|
|
|
|
libsecp256k1_name =
|
|
if stdenv.isLinux then "libsecp256k1.so.0"
|
|
else if stdenv.isDarwin then "libsecp256k1.0.dylib"
|
|
else "libsecp256k1${stdenv.hostPlatform.extensions.sharedLibrary}";
|
|
|
|
libzbar_name =
|
|
if stdenv.isLinux then "libzbar.so.0"
|
|
else "libzbar${stdenv.hostPlatform.extensions.sharedLibrary}";
|
|
|
|
# Not provided in official source releases, which are what upstream signs.
|
|
tests = fetchFromGitHub {
|
|
owner = "spesmilo";
|
|
repo = "electrum";
|
|
rev = version;
|
|
sha256 = "1di8ba77kgapcys0d7h5nx1qqakv3s60c6sp8skw8p69ramsl73c";
|
|
|
|
extraPostFetch = ''
|
|
mv $out ./all
|
|
mv ./all/electrum/tests $out
|
|
'';
|
|
};
|
|
in
|
|
|
|
python3Packages.buildPythonApplication {
|
|
pname = "electrum";
|
|
inherit version;
|
|
|
|
src = fetchurl {
|
|
url = "https://download.electrum.org/${version}/Electrum-${version}.tar.gz";
|
|
sha256 = "1g00cj1pmckd4xis8r032wmraiv3vd3zc803hnyxa2bnhj8z3bg2";
|
|
};
|
|
|
|
postUnpack = ''
|
|
# can't symlink, tests get confused
|
|
cp -ar ${tests} $sourceRoot/electrum/tests
|
|
'';
|
|
|
|
nativeBuildInputs = stdenv.lib.optionals enableQt [ wrapQtAppsHook ];
|
|
|
|
propagatedBuildInputs = with python3Packages; [
|
|
aiorpcx
|
|
aiohttp
|
|
aiohttp-socks
|
|
dnspython
|
|
ecdsa
|
|
jsonrpclib-pelix
|
|
matplotlib
|
|
pbkdf2
|
|
protobuf
|
|
pyaes
|
|
pycryptodomex
|
|
pysocks
|
|
qrcode
|
|
requests
|
|
tlslite-ng
|
|
|
|
# plugins
|
|
keepkey
|
|
trezor
|
|
btchip
|
|
|
|
# TODO plugins
|
|
# amodem
|
|
] ++ stdenv.lib.optionals enableQt [ pyqt5 qdarkstyle ];
|
|
|
|
preBuild = ''
|
|
sed -i 's,usr_share = .*,usr_share = "'$out'/share",g' setup.py
|
|
substituteInPlace ./electrum/ecc_fast.py \
|
|
--replace ${libsecp256k1_name} ${secp256k1}/lib/libsecp256k1${stdenv.hostPlatform.extensions.sharedLibrary}
|
|
'' + (if enableQt then ''
|
|
substituteInPlace ./electrum/qrscanner.py \
|
|
--replace ${libzbar_name} ${zbar.lib}/lib/libzbar${stdenv.hostPlatform.extensions.sharedLibrary}
|
|
'' else ''
|
|
sed -i '/qdarkstyle/d' contrib/requirements/requirements.txt
|
|
'');
|
|
|
|
postInstall = stdenv.lib.optionalString stdenv.isLinux ''
|
|
# Despite setting usr_share above, these files are installed under
|
|
# $out/nix ...
|
|
mv $out/${python3.sitePackages}/nix/store"/"*/share $out
|
|
rm -rf $out/${python3.sitePackages}/nix
|
|
|
|
substituteInPlace $out/share/applications/electrum.desktop \
|
|
--replace 'Exec=sh -c "PATH=\"\\$HOME/.local/bin:\\$PATH\"; electrum %u"' \
|
|
"Exec=$out/bin/electrum %u" \
|
|
--replace 'Exec=sh -c "PATH=\"\\$HOME/.local/bin:\\$PATH\"; electrum --testnet %u"' \
|
|
"Exec=$out/bin/electrum --testnet %u"
|
|
|
|
'';
|
|
|
|
postFixup = stdenv.lib.optionalString enableQt ''
|
|
wrapQtApp $out/bin/electrum
|
|
'';
|
|
|
|
checkInputs = with python3Packages; [ pytest ];
|
|
|
|
checkPhase = ''
|
|
py.test electrum/tests
|
|
$out/bin/electrum help >/dev/null
|
|
'';
|
|
|
|
passthru.updateScript = import ./update.nix {
|
|
inherit (stdenv) lib;
|
|
inherit
|
|
writeScript
|
|
common-updater-scripts
|
|
bash
|
|
coreutils
|
|
curl
|
|
gnupg
|
|
gnugrep
|
|
gnused
|
|
nix
|
|
;
|
|
};
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "A lightweight Bitcoin wallet";
|
|
longDescription = ''
|
|
An easy-to-use Bitcoin client featuring wallets generated from
|
|
mnemonic seeds (in addition to other, more advanced, wallet options)
|
|
and the ability to perform transactions without downloading a copy
|
|
of the blockchain.
|
|
'';
|
|
homepage = https://electrum.org/;
|
|
license = licenses.mit;
|
|
platforms = platforms.all;
|
|
maintainers = with maintainers; [ ehmry joachifm np ];
|
|
};
|
|
}
|