dda50e7348
gopass maintains a ~/.cache/gopass/gpg-binary.loc file which stores an absolute path to the gpg executable, overriding (and ignoring) the environment $PATH. This creates a situation where gopass will work for a period of time after install, but after gpg is upgraded and a 'nix-store --gc' is performed, the cached gpg path will throw an error. A gopass maintainer has declared this a wont-fix in https://github.com/gopasspw/gopass/issues/1662 As a workaround, add a --run clause in the wrapper script that removes this cache file. Once (if) upstream fixes this issue, this cruft can be removed. Signed-off-by: Sirio Balmelli <sirio@b-ad.ch>
76 lines
2.1 KiB
Nix
76 lines
2.1 KiB
Nix
{ stdenv
|
|
, makeWrapper
|
|
, buildGoModule
|
|
, fetchFromGitHub
|
|
, installShellFiles
|
|
, git
|
|
, gnupg
|
|
, xclip
|
|
, wl-clipboard
|
|
, passAlias ? false
|
|
}:
|
|
|
|
buildGoModule rec {
|
|
pname = "gopass";
|
|
version = "1.10.1";
|
|
|
|
nativeBuildInputs = [ installShellFiles makeWrapper ];
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "gopasspw";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
sha256 = "0dhh64mxfhk610wr7bpakzgmc4a4iyhfkkl3qhjp6a46g9iygana";
|
|
};
|
|
|
|
vendorSha256 = "07wv6yahx4yzr3h1x93x4r5rvw8wbfk836f04b4r9xjbnpq7lb2a";
|
|
|
|
doCheck = false;
|
|
|
|
buildFlagsArray = [ "-ldflags=-s -w -X main.version=${version} -X main.commit=${src.rev}" ];
|
|
|
|
wrapperPath = stdenv.lib.makeBinPath (
|
|
[
|
|
git
|
|
gnupg
|
|
xclip
|
|
] ++ stdenv.lib.optional stdenv.isLinux wl-clipboard
|
|
);
|
|
|
|
postInstall = ''
|
|
for shell in bash fish zsh; do
|
|
$out/bin/gopass completion $shell > gopass.$shell
|
|
installShellCompletion gopass.$shell
|
|
done
|
|
'' + stdenv.lib.optionalString passAlias ''
|
|
ln -s $out/bin/gopass $out/bin/pass
|
|
'';
|
|
|
|
# --run to work around WONTFIX in https://github.com/gopasspw/gopass/issues/1662
|
|
postFixup = ''
|
|
for bin in $out/bin/*; do
|
|
wrapProgram $bin \
|
|
--prefix PATH : "${wrapperPath}" \
|
|
--run 'rm -f "''${XDG_CONFIG_HOME:-~/.config}/gopass/gpg-binary.loc"'
|
|
done
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "The slightly more awesome Standard Unix Password Manager for Teams. Written in Go";
|
|
homepage = "https://www.gopass.pw/";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ andir rvolosatovs ];
|
|
platforms = platforms.unix;
|
|
|
|
longDescription = ''
|
|
gopass is a rewrite of the pass password manager in Go with the aim of
|
|
making it cross-platform and adding additional features. Our target
|
|
audience are professional developers and sysadmins (and especially teams
|
|
of those) who are well versed with a command line interface. One explicit
|
|
goal for this project is to make it more approachable to non-technical
|
|
users. We go by the UNIX philosophy and try to do one thing and do it
|
|
well, providing a stellar user experience and a sane, simple interface.
|
|
'';
|
|
};
|
|
}
|