f5dfe78a1e
This patch add a new argument to Nixpkgs default expression named "overlays". By default, the value of the argument is either taken from the environment variable `NIXPKGS_OVERLAYS`, or from the directory `~/.nixpkgs/overlays/`. If the environment variable does not name a valid directory then this mechanism would fallback on the home directory. If the home directory does not exists it will fallback on an empty list of overlays. The overlays directory should contain the list of extra Nixpkgs stages which would be used to extend the content of Nixpkgs, with additional set of packages. The overlays, i-e directory, files, symbolic links are used in alphabetical order. The simplest overlay which extends Nixpkgs with nothing looks like: ```nix self: super: { } ``` More refined overlays can use `super` as the basis for building new packages, and `self` as a way to query the final result of the fix-point. An example of overlay which extends Nixpkgs with a small set of packages can be found at: https://github.com/nbp/nixpkgs-mozilla/blob/nixpkgs-overlay/moz-overlay.nix To use this file, checkout the repository and add a symbolic link to the `moz-overlay.nix` file in `~/.nixpkgs/overlays` directory.
155 lines
3.7 KiB
Nix
155 lines
3.7 KiB
Nix
{ lib
|
||
, system, platform, crossSystem, config, overlays
|
||
}:
|
||
|
||
assert crossSystem == null;
|
||
|
||
let
|
||
|
||
shell =
|
||
if system == "i686-freebsd" || system == "x86_64-freebsd" then "/usr/local/bin/bash"
|
||
else "/bin/bash";
|
||
|
||
path =
|
||
(if system == "i686-solaris" then [ "/usr/gnu" ] else []) ++
|
||
(if system == "i686-netbsd" then [ "/usr/pkg" ] else []) ++
|
||
(if system == "x86_64-solaris" then [ "/opt/local/gnu" ] else []) ++
|
||
["/" "/usr" "/usr/local"];
|
||
|
||
prehookBase = ''
|
||
# Disable purity tests; it's allowed (even needed) to link to
|
||
# libraries outside the Nix store (like the C library).
|
||
export NIX_ENFORCE_PURITY=
|
||
export NIX_ENFORCE_NO_NATIVE="''${NIX_ENFORCE_NO_NATIVE-1}"
|
||
'';
|
||
|
||
prehookFreeBSD = ''
|
||
${prehookBase}
|
||
|
||
alias make=gmake
|
||
alias tar=gtar
|
||
alias sed=gsed
|
||
export MAKE=gmake
|
||
shopt -s expand_aliases
|
||
'';
|
||
|
||
prehookOpenBSD = ''
|
||
${prehookBase}
|
||
|
||
alias make=gmake
|
||
alias grep=ggrep
|
||
alias mv=gmv
|
||
alias ln=gln
|
||
alias sed=gsed
|
||
alias tar=gtar
|
||
|
||
export MAKE=gmake
|
||
shopt -s expand_aliases
|
||
'';
|
||
|
||
prehookNetBSD = ''
|
||
${prehookBase}
|
||
|
||
alias make=gmake
|
||
alias sed=gsed
|
||
alias tar=gtar
|
||
export MAKE=gmake
|
||
shopt -s expand_aliases
|
||
'';
|
||
|
||
# prevent libtool from failing to find dynamic libraries
|
||
prehookCygwin = ''
|
||
${prehookBase}
|
||
|
||
shopt -s expand_aliases
|
||
export lt_cv_deplibs_check_method=pass_all
|
||
'';
|
||
|
||
extraBuildInputsCygwin = [
|
||
../cygwin/all-buildinputs-as-runtimedep.sh
|
||
../cygwin/wrap-exes-to-find-dlls.sh
|
||
] ++ (if system == "i686-cygwin" then [
|
||
../cygwin/rebase-i686.sh
|
||
] else if system == "x86_64-cygwin" then [
|
||
../cygwin/rebase-x86_64.sh
|
||
] else []);
|
||
|
||
# A function that builds a "native" stdenv (one that uses tools in
|
||
# /usr etc.).
|
||
makeStdenv =
|
||
{ cc, fetchurl, extraPath ? [], overrides ? (self: super: { }) }:
|
||
|
||
import ../generic {
|
||
preHook =
|
||
if system == "i686-freebsd" then prehookFreeBSD else
|
||
if system == "x86_64-freebsd" then prehookFreeBSD else
|
||
if system == "i686-openbsd" then prehookOpenBSD else
|
||
if system == "i686-netbsd" then prehookNetBSD else
|
||
if system == "i686-cygwin" then prehookCygwin else
|
||
if system == "x86_64-cygwin" then prehookCygwin else
|
||
prehookBase;
|
||
|
||
extraBuildInputs =
|
||
if system == "i686-cygwin" then extraBuildInputsCygwin else
|
||
if system == "x86_64-cygwin" then extraBuildInputsCygwin else
|
||
[];
|
||
|
||
initialPath = extraPath ++ path;
|
||
|
||
fetchurlBoot = fetchurl;
|
||
|
||
inherit system shell cc overrides config;
|
||
};
|
||
|
||
in
|
||
|
||
[
|
||
|
||
({}: rec {
|
||
__raw = true;
|
||
|
||
stdenv = makeStdenv {
|
||
cc = null;
|
||
fetchurl = null;
|
||
};
|
||
|
||
cc = import ../../build-support/cc-wrapper {
|
||
name = "cc-native";
|
||
nativeTools = true;
|
||
nativeLibc = true;
|
||
nativePrefix = { # switch
|
||
"i686-solaris" = "/usr/gnu";
|
||
"x86_64-solaris" = "/opt/local/gcc47";
|
||
}.${system} or "/usr";
|
||
inherit stdenv;
|
||
};
|
||
|
||
fetchurl = import ../../build-support/fetchurl {
|
||
inherit stdenv;
|
||
# Curl should be in /usr/bin or so.
|
||
curl = null;
|
||
};
|
||
|
||
})
|
||
|
||
# First build a stdenv based only on tools outside the store.
|
||
(prevStage: {
|
||
inherit system crossSystem platform config overlays;
|
||
stdenv = makeStdenv {
|
||
inherit (prevStage) cc fetchurl;
|
||
} // { inherit (prevStage) fetchurl; };
|
||
})
|
||
|
||
# Using that, build a stdenv that adds the ‘xz’ command (which most systems
|
||
# don't have, so we mustn't rely on the native environment providing it).
|
||
(prevStage: {
|
||
inherit system crossSystem platform config overlays;
|
||
stdenv = makeStdenv {
|
||
inherit (prevStage.stdenv) cc fetchurl;
|
||
extraPath = [ prevStage.xz ];
|
||
overrides = self: super: { inherit (prevStage) xz; };
|
||
};
|
||
})
|
||
|
||
]
|