6c4de0b5fe
OE currently builds dtb files with its own custom targets by specifying each dtb file as makefile target, this creates bad dtb for rpi64 bit. This patch calles 'make dtbs' at the end which regenerates the correct dtb files This makes the vc4 initialize properly on rpi64 Signed-off-by: Khem Raj <raj.khem@gmail.com>
59 lines
1.9 KiB
PHP
59 lines
1.9 KiB
PHP
require linux-rpi.inc
|
|
inherit linux-raspberrypi-base
|
|
|
|
DESCRIPTION = "Linux Kernel for Raspberry Pi"
|
|
SECTION = "kernel"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
|
|
|
|
COMPATIBLE_MACHINE = "^rpi$"
|
|
|
|
PE = "1"
|
|
PV = "${LINUX_VERSION}+git${SRCPV}"
|
|
|
|
KCONFIG_MODE = "--alldefconfig"
|
|
KBUILD_DEFCONFIG_raspberrypi ?= "bcmrpi_defconfig"
|
|
KBUILD_DEFCONFIG_raspberrypi2 ?= "bcm2709_defconfig"
|
|
KBUILD_DEFCONFIG_raspberrypi3 ?= "bcm2709_defconfig"
|
|
KBUILD_DEFCONFIG_raspberrypi3-64 ?= "bcmrpi3_defconfig"
|
|
|
|
# CMDLINE for raspberrypi
|
|
CMDLINE ?= "dwc_otg.lpm_enable=0 console=serial0,115200 root=/dev/mmcblk0p2 rootfstype=ext4 rootwait"
|
|
|
|
# Add the kernel debugger over console kernel command line option if enabled
|
|
CMDLINE_append = ' ${@base_conditional("ENABLE_KGDB", "1", "kgdboc=serial0,115200", "", d)}'
|
|
|
|
# Disable rpi logo on boot
|
|
CMDLINE_append += ' ${@base_conditional("DISABLE_RPI_BOOT_LOGO", "1", "logo.nologo", "", d)}'
|
|
|
|
UDEV_GE_141 ?= "1"
|
|
|
|
KERNEL_MODULE_AUTOLOAD += "${@bb.utils.contains("MACHINE_FEATURES", "pitft28r", "stmpe-ts", "", d)}"
|
|
|
|
# Set programmatically some variables during recipe parsing
|
|
# See http://www.yoctoproject.org/docs/current/bitbake-user-manual/bitbake-user-manual.html#anonymous-python-functions
|
|
python __anonymous () {
|
|
kerneltype = d.getVar('KERNEL_IMAGETYPE')
|
|
kerneldt = get_dts(d, d.getVar('LINUX_VERSION'))
|
|
d.setVar("KERNEL_DEVICETREE", kerneldt)
|
|
}
|
|
|
|
do_compile_append_raspberrypi3-64() {
|
|
cc_extra=$(get_cc_option)
|
|
oe_runmake dtbs CC="${KERNEL_CC} $cc_extra " LD="${KERNEL_LD}" ${KERNEL_EXTRA_ARGS}
|
|
}
|
|
|
|
do_install_prepend() {
|
|
install -d ${D}/lib/firmware
|
|
}
|
|
|
|
do_deploy_append() {
|
|
# Deploy cmdline.txt
|
|
install -d ${DEPLOYDIR}/bcm2835-bootfiles
|
|
PITFT="${@bb.utils.contains("MACHINE_FEATURES", "pitft", "1", "0", d)}"
|
|
if [ ${PITFT} = "1" ]; then
|
|
PITFT_PARAMS="fbcon=map:10 fbcon=font:VGA8x8"
|
|
fi
|
|
echo "${CMDLINE}${PITFT_PARAMS}" > ${DEPLOYDIR}/bcm2835-bootfiles/cmdline.txt
|
|
}
|