CMake as an alternative to autotools (experimental)

Change-Id: Ibc59323e849810531dd0963e85493efad3b86857
Signed-off-by: Damjan Marion <damarion@cisco.com>

.gitignore

@@ -66,7 +66,6 @@ test-driver
 .cproject
 .pydevproject
 .vscode/
-CMakeLists.txt
 cmake-build*/
 
 # cscope and ctags

Makefile

@@ -21,6 +21,10 @@ STARTUP_DIR?=$(PWD)
 MACHINE=$(shell uname -m)
 SUDO?=sudo
 
+ifeq ($(findstring $(MAKECMDGOALS),verify pkg-deb pkg-rpm test),)
+export vpp_uses_cmake?=yes
+endif
+
 ,:=,
 define disable_plugins
 $(if $(1), \
@@ -66,6 +70,7 @@ DEB_DEPENDS += libconfuse-dev git-review exuberant-ctags cscope pkg-config
 DEB_DEPENDS += lcov chrpath autoconf indent clang-format libnuma-dev
 DEB_DEPENDS += python-all python-dev python-virtualenv python-pip libffi6 check
 DEB_DEPENDS += libboost-all-dev libffi-dev python-ply libmbedtls-dev
+DEB_DEPENDS += cmake ninja-build
 ifeq ($(OS_VERSION_ID),14.04)
 	DEB_DEPENDS += openjdk-8-jdk-headless
 	DEB_DEPENDS += libssl-dev

build-data/packages/vpp.mk

@@ -12,6 +12,7 @@
 # limitations under the License.
 
 vpp_source = src
+ifneq ($(vpp_uses_cmake),yes)
 
 ifeq ($($(PLATFORM)_dpdk_shared_lib),yes)
 vpp_configure_args = --enable-dpdk-shared
@@ -49,3 +50,18 @@ endif
 ifeq ($($(PLATFORM)_enable_tests),yes)
 vpp_configure_args += --enable-tests
 endif
+
+else
+vpp_configure_depend += dpdk-install
+vpp_configure = \
+  cd $(PACKAGE_BUILD_DIR) && \
+  cmake -G Ninja \
+    -DCMAKE_INSTALL_PREFIX:PATH=$(PACKAGE_INSTALL_DIR) \
+    -DCMAKE_C_FLAGS="$($(TAG)_TAG_CFLAGS)" \
+    -DDPDK_INCLUDE_DIR_HINT="$(PACKAGE_INSTALL_DIR)/../dpdk/include" \
+    -DDPDK_LIB_DIR_HINT="$(PACKAGE_INSTALL_DIR)/../dpdk/lib" \
+    $(call find_source_fn,$(PACKAGE_SOURCE))
+#vpp_make_args = --no-print-directory
+vpp_build = cmake --build $(PACKAGE_BUILD_DIR)
+vpp_install = cmake --build $(PACKAGE_BUILD_DIR) -- install | grep -v 'Set runtime path'
+endif

build-data/platforms/vpp.mk

@@ -23,6 +23,9 @@ vpp_native_tools = vppapigen
 
 vpp_uses_dpdk = yes
 
+# use cmake as an alternative to autotools
+# vpp_uses_cmake = yes
+
 # Uncoment to enable building unit tests
 # vpp_enable_tests = yes
 

src/CMakeLists.txt

@@ -0,0 +1,161 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
+
+project(vpp C)
+
+include(CheckCCompilerFlag)
+
+##############################################################################
+# CPU optimizations and multiarch support
+##############################################################################
+if(CMAKE_SYSTEM_PROCESSOR MATCHES "amd64.*|x86_64.*|AMD64.*")
+  set(CMAKE_C_FLAGS "-march=corei7 -mtune=corei7-avx ${CMAKE_C_FLAGS}")
+  check_c_compiler_flag("-march=core-avx2" AVX2)
+  if(AVX2)
+    list(APPEND MARCH_VARIANTS "avx2\;-march=core-avx2 -mtune=core-avx2")
+  endif()
+  check_c_compiler_flag("-march=skylake-avx512" AVX512)
+  if(AVX512)
+    list(APPEND MARCH_VARIANTS "avx512\;-march=skylake-avx512 -mtune=skylake-avx512")
+  endif()
+elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(aarch64.*|AARCH64.*)")
+  set(CMAKE_C_FLAGS "-march=armv8-a+crc ${CMAKE_C_FLAGS}")
+endif()
+
+macro(vpp_library_set_multiarch_sources lib)
+  foreach(V ${MARCH_VARIANTS})
+    list(GET V 0 VARIANT)
+    list(GET V 1 VARIANT_FLAGS)
+    set(l ${lib}_${VARIANT})
+    add_library(${l} OBJECT ${ARGN})
+    set_target_properties(${l} PROPERTIES POSITION_INDEPENDENT_CODE ON)
+    target_compile_options(${l} PUBLIC "-DCLIB_MARCH_VARIANT=${VARIANT}")
+    separate_arguments(VARIANT_FLAGS)
+    target_compile_options(${l} PUBLIC ${VARIANT_FLAGS})
+    target_sources(${lib} PRIVATE $<TARGET_OBJECTS:${l}>)
+  endforeach()
+endmacro()
+
+##############################################################################
+# build config
+##############################################################################
+set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
+set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
+set(CMAKE_C_FLAGS_COMMON "-DFORTIFY_SOURCE=2 -fstack-protector-all -Werror")
+set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} ${CMAKE_C_FLAGS_COMMON} -DCLIB_DEBUG")
+set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${CMAKE_C_FLAGS_COMMON}")
+
+##############################################################################
+# ccache
+##############################################################################
+option(VPP_USE_CCACHE "Use ccache compiler cache." ON)
+if(VPP_USE_CCACHE)
+  find_program(CCACHE_FOUND ccache)
+  message(STATUS "Looking for ccache")
+  if(CCACHE_FOUND)
+    message(STATUS "Looking for ccache - found")
+    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
+    set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
+  else(CCACHE_FOUND)
+    message(STATUS "Looking for ccache - not found")
+  endif(CCACHE_FOUND)
+endif(VPP_USE_CCACHE)
+
+##############################################################################
+# install config
+##############################################################################
+set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
+set(CMAKE_INSTALL_MESSAGE NEVER)
+
+message(STATUS "CMAKE_C_FLAGS: ${CMAKE_C_FLAGS}")
+message(STATUS "We are on a ${CMAKE_SYSTEM_NAME} system")
+message(STATUS "The host processor is ${CMAKE_HOST_SYSTEM_PROCESSOR}")
+
+include_directories (
+	${CMAKE_SOURCE_DIR}
+	${CMAKE_BINARY_DIR}
+	${CMAKE_BINARY_DIR}/include
+)
+set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
+
+set(THREADS_PREFER_PTHREAD_FLAG ON)
+find_package(Threads REQUIRED)
+find_package(OpenSSL REQUIRED)
+include_directories(${OPENSSL_INCLUDE_DIR})
+
+add_definitions(-DHAVE_MEMFD_CREATE -DVPP_API_TEST_BUILTIN=1)
+
+##############################################################################
+# API
+##############################################################################
+function(vpp_generate_api_header file)
+  set (output_name ${CMAKE_CURRENT_BINARY_DIR}/${file}.h)
+  get_filename_component(output_dir ${output_name} DIRECTORY)
+  add_custom_command (OUTPUT ${output_name}
+    COMMAND mkdir -p ${output_dir}
+    COMMAND ${CMAKE_SOURCE_DIR}/tools/vppapigen/vppapigen
+    ARGS --includedir ${CMAKE_SOURCE_DIR} --input ${CMAKE_CURRENT_SOURCE_DIR}/${file} --output ${output_name}
+    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${file}
+    COMMENT "Generating API header ${file}.h"
+  )
+endfunction()
+
+function(vpp_add_api_files target)
+  unset(header_files)
+  foreach(file ${ARGN})
+    vpp_generate_api_header (${file})
+    list (APPEND header_files ${file}.h)
+  endforeach()
+  add_custom_target(${target} DEPENDS ${header_files})
+endfunction()
+
+add_custom_target(api_headers
+  DEPENDS vlibmemory_api_headers vnet_api_headers vpp_api_headers
+)
+
+##############################################################################
+# header files
+##############################################################################
+function (vpp_add_header_files path)
+  foreach(file ${ARGN})
+    get_filename_component(dir ${file} DIRECTORY)
+    install(FILES ${file} DESTINATION include/${path}/${dir})
+  endforeach()
+endfunction()
+
+##############################################################################
+# subdirs
+##############################################################################
+foreach (DIR vppinfra svm vlib vlibmemory vnet vpp vcl plugins)
+  add_subdirectory(${DIR})
+endforeach ()
+
+##############################################################################
+# DEB Packaging
+##############################################################################
+set(CPACK_GENERATOR "DEB")
+set(CPACK_DEBIAN_PACKAGE_MAINTAINER "VPP Team")
+set(CPACK_PACKAGE_NAME "vpp")
+set(CPACK_PACKAGE_VENDOR "fd.io")
+set(CPACK_PACKAGE_VERSION "18.08")
+set(CPACK_DEB_COMPONENT_INSTALL ON)
+set(CPACK_COMPONENTS_IGNORE_GROUPS 1)
+set(CPACK_DEBIAN_VPP_PACKAGE_NAME "vpp")
+set(CPACK_DEBIAN_VPP_FILE_NAME "vpp.deb")
+set(CPACK_DEBIAN_DEV_PACKAGE_NAME "vpp-dev")
+set(CPACK_DEBIAN_DEV_FILE_NAME "vpp-dev.deb")
+set(CPACK_DEBIAN_PLUGINS_PACKAGE_NAME "vpp-plugins")
+set(CPACK_DEBIAN_PLUGINS_FILE_NAME "vpp-plugins.deb")
+include(CPack)

src/plugins/CMakeLists.txt

@@ -0,0 +1,63 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include_directories (
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+)
+
+macro(add_vpp_plugin plugin_name)
+  set(api_headers)
+  foreach(f ${ARGN})
+     if(${f} MATCHES ".*\.api$")
+       vpp_generate_api_header(${f})
+       list(APPEND api_headers ${f}.h)
+     endif()
+  endforeach()
+  add_library(${plugin_name} SHARED ${ARGN} ${api_headers})
+  add_dependencies(${plugin_name} vpp_version_h api_headers)
+  set_target_properties(${plugin_name} PROPERTIES
+    PREFIX ""
+    LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_plugins)
+  install(TARGETS ${plugin_name} DESTINATION lib/vpp_plugins COMPONENT plugins)
+endmacro()
+
+macro(add_vpp_api_test_plugin plugin_name)
+  set(api_headers)
+  foreach(f ${ARGN})
+     if(${f} MATCHES ".*\.api$")
+       vpp_generate_api_header(${f})
+       list(APPEND api_headers ${f}.h)
+     endif()
+  endforeach()
+  add_library(${plugin_name} SHARED ${ARGN} ${api_headers})
+  add_dependencies(${plugin_name} api_headers)
+  set_target_properties(${plugin_name} PROPERTIES PREFIX "")
+  set_target_properties(${plugin_name} PROPERTIES
+    PREFIX ""
+    LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}//vpp_api_test_plugins)
+  install(TARGETS ${plugin_name} DESTINATION lib/vpp_api_test_plugins COMPONENT
+	  plugins)
+endmacro()
+
+##############################################################################
+# find and add all plugin subdirs
+############################################################################
+FILE(GLOB files RELATIVE
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}/*/CMakeLists.txt
+)
+foreach (f ${files})
+  get_filename_component(dir ${f} DIRECTORY)
+  add_subdirectory(${dir})
+endforeach()

src/plugins/abf/CMakeLists.txt

@@ -0,0 +1,19 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(abf_plugin
+  abf.api
+  abf_api.c
+  abf_itf_attach.c
+  abf_policy.c
+)

src/plugins/acl/CMakeLists.txt

@@ -0,0 +1,21 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(acl_plugin
+  acl.api
+  acl.c
+  hash_lookup.c
+  lookup_context.c
+  sess_mgmt_node.c
+  dataplane_node.c
+)

src/plugins/avf/CMakeLists.txt

@@ -0,0 +1,28 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(avf_plugin
+  cli.c
+  device.c
+  format.c
+  input.c
+  output.c
+  plugin.c
+  avf_api.c
+  avf.api
+)
+
+vpp_library_set_multiarch_sources(avf_plugin
+  input.c
+  output.c
+)

src/plugins/cdp/CMakeLists.txt

@@ -0,0 +1,26 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(cdp_plugin
+  cdp.api
+  cdp.c
+  cdp_input.c
+  cdp_node.c
+  cdp_periodic.c
+)
+
+add_vpp_api_test_plugin(cdp_test_plugin
+  cdp.api
+  cdp_test.c
+)
+

src/plugins/dpdk/CMakeLists.txt

@@ -0,0 +1,100 @@
+# Copyright (c) 2016 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+##############################################################################
+# Find lib and include files
+##############################################################################
+find_path(DPDK_INCLUDE_DIR PATH_SUFFIXES dpdk NAMES rte_config.h HINTS
+	  ${DPDK_INCLUDE_DIR_HINT})
+find_library(DPDK_LIB NAMES libdpdk.a HINTS ${DPDK_LIB_DIR_HINT})
+
+##############################################################################
+# Find DPDK Version
+##############################################################################
+file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/dpdk_version.c
+"
+#include <stdio.h>
+#include <rte_version.h>
+int main()
+{
+  puts(strchr(rte_version(), ' ') + 1);
+  return 0;
+}
+")
+
+try_compile(DPDK_VERSION_COMPILED
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}/dpdk_version.c
+  CMAKE_FLAGS
+  -DINCLUDE_DIRECTORIES=${DPDK_INCLUDE_DIR}
+  COPY_FILE ${CMAKE_CURRENT_BINARY_DIR}/dpdk_version.bin
+)
+
+if(DPDK_VERSION_COMPILED)
+  execute_process(
+    WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
+    COMMAND ./dpdk_version.bin
+    OUTPUT_VARIABLE DPDK_VERSION
+    OUTPUT_STRIP_TRAILING_WHITESPACE
+  )
+endif()
+
+file(REMOVE
+  ${CMAKE_CURRENT_BINARY_DIR}/dpdk_version.c
+  ${CMAKE_CURRENT_BINARY_DIR}/dpdk_version.bin
+)
+
+
+##############################################################################
+# DPDK plugin
+##############################################################################
+if(DPDK_INCLUDE_DIR AND DPDK_LIB)
+  include_directories (${DPDK_INCLUDE_DIR})
+  add_vpp_plugin(dpdk_plugin
+    buffer.c
+    main.c
+    thread.c
+    api/dpdk_api.c
+    api/dpdk_test.c
+    device/cli.c
+    device/common.c
+    device/device.c
+    device/flow.c
+    device/format.c
+    device/init.c
+    device/node.c
+    hqos/hqos.c
+    ipsec/cli.c
+    ipsec/crypto_node.c
+    ipsec/esp_decrypt.c
+    ipsec/esp_encrypt.c
+    ipsec/ipsec.c
+    api/dpdk.api
+  )
+
+  vpp_library_set_multiarch_sources(dpdk_plugin
+    buffer.c
+    device/device.c
+    device/node.c
+  )
+
+  get_filename_component(DPDK_LIB_DIR ${DPDK_LIB} DIRECTORY)
+  set(DPDK_LINK_FLAGS "-L${DPDK_LIB_DIR} -Wl,--whole-archive,${DPDK_LIB},--no-whole-archive")
+  set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,--exclude-libs,libIPSec_MB.a,-l:libIPSec_MB.a")
+  set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,-lnuma")
+  set_target_properties(dpdk_plugin PROPERTIES LINK_FLAGS "${DPDK_LINK_FLAGS}")
+  message("-- Found DPDK ${DPDK_VERSION}: ${DPDK_INCLUDE_DIR} ${DPDK_LIB}")
+else()
+  message("-- DPDK not found - dpdk_plugin disabled")
+endif()
+

src/plugins/flowprobe/CMakeLists.txt

@@ -0,0 +1,24 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(flowprobe_plugin
+  flowprobe.api
+  flowprobe.c
+  node.c
+)
+
+add_vpp_api_test_plugin(flowprobe_test_plugin
+  flowprobe.api
+  flowprobe_test.c
+)
+

src/plugins/gbp/CMakeLists.txt

@@ -0,0 +1,27 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(gbp_plugin
+  gbp.api
+  gbp_subnet.c
+  gbp_contract.c
+  gbp_endpoint.c
+  gbp_endpoint_group.c
+  gbp_classify.c
+  gbp_recirc.c
+  gbp_policy.c
+  gbp_policy_dpo.c
+  gbp_fwd.c
+  gbp_fwd_dpo.c
+  gbp_api.c
+)

src/plugins/gtpu/CMakeLists.txt

@@ -0,0 +1,26 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(gtpu_plugin
+  gtpu.api
+  gtpu.c
+  gtpu_api.c
+  gtpu_decap.c
+  gtpu_encap.c
+)
+
+add_vpp_api_test_plugin(gtpu_test_plugin
+  gtpu.api
+  gtpu_test.c
+)
+

src/plugins/igmp/CMakeLists.txt

@@ -0,0 +1,29 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(igmp_plugin
+  igmp.api
+  igmp.c
+  igmp_query.c
+  igmp_report.c
+  igmp_group.c
+  igmp_src.c
+  igmp_config.c
+  igmp_cli.c
+  igmp_api.c
+  igmp_input.c
+  igmp_timer.c
+  igmp_pkt.c
+  igmp_ssm_range.c
+  igmp_format.c
+)

src/plugins/ila/CMakeLists.txt

@@ -0,0 +1,15 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(ila_plugin ila.c)
+

src/plugins/ioam/CMakeLists.txt

@@ -0,0 +1,99 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(ioam_plugin
+  # iOAM Proof of Transit
+  lib-pot/pot.api
+  lib-pot/pot_util.c
+  encap/ip6_ioam_pot.c
+  lib-pot/pot_api.c
+
+  # iOAM trace export for IPv6
+  export/ioam_export.api
+  export/ioam_export.c
+  export/node.c
+  export/ioam_export_thread.c
+
+  # iOAM Trace
+  lib-trace/trace.api
+  lib-trace/trace_util.c
+  encap/ip6_ioam_trace.c
+  lib-trace/trace_api.c
+
+  # VxLAN-GPE
+  lib-vxlan-gpe/ioam_vxlan_gpe.api
+  lib-vxlan-gpe/ioam_encap.c
+  lib-vxlan-gpe/ioam_decap.c
+  lib-vxlan-gpe/ioam_transit.c
+  lib-vxlan-gpe/ioam_pop.c
+  lib-vxlan-gpe/vxlan_gpe_api.c
+  lib-vxlan-gpe/vxlan_gpe_ioam_trace.c
+  lib-vxlan-gpe/vxlan_gpe_ioam.c
+  export-vxlan-gpe/vxlan_gpe_ioam_export.api
+  export-vxlan-gpe/vxlan_gpe_ioam_export.c
+  export-vxlan-gpe/vxlan_gpe_node.c
+  export-vxlan-gpe/vxlan_gpe_ioam_export_thread.c
+
+  # iOAM E2E
+  encap/ip6_ioam_e2e.c
+  encap/ip6_ioam_seqno.c
+  lib-e2e/ioam_seqno_lib.c
+
+  # ipfix collector
+  ipfixcollector/ipfixcollector.c
+  ipfixcollector/node.c
+
+  # iOAM Analyse
+  analyse/ip6/ip6_ioam_analyse.c
+  analyse/ip6/node.c
+  analyse/ioam_summary_export.c
+
+  # iOAM record cache and rewrite
+  ip6/ioam_cache.api
+  ip6/ioam_cache.c
+  ip6/ioam_cache_node.c
+  ip6/ioam_cache_tunnel_select_node.c
+
+  # udp ping
+  udp-ping/udp_ping.api
+  udp-ping/udp_ping_node.c
+  udp-ping/udp_ping_util.c
+  udp-ping/udp_ping_export.c
+  udp-ping/udp_ping_api.c
+)
+
+add_vpp_api_test_plugin(ioam_pot_test_plugin
+  lib-pot/pot.api
+  lib-pot/pot_test.c
+)
+
+add_vpp_api_test_plugin(ioam_export_test_plugin
+  export/ioam_export.api
+  export/ioam_export_test.c
+)
+
+add_vpp_api_test_plugin(ioam_trace_test_plugin
+  lib-trace/trace.api
+  lib-trace/trace_test.c
+)
+
+add_vpp_api_test_plugin(ioam_vxlan_gpe_test_plugin
+  lib-vxlan-gpe/ioam_vxlan_gpe.api
+  lib-vxlan-gpe/vxlan_gpe_test.c
+)
+
+add_vpp_api_test_plugin(ioam_udp_ping_test_plugin
+  udp-ping/udp_ping.api
+  udp-ping/udp_ping_test.c
+)
+

src/plugins/ixge/CMakeLists.txt

@@ -0,0 +1,16 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(ixge_plugin
+  ixge.c
+)

src/plugins/l2e/CMakeLists.txt

@@ -0,0 +1,18 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(l2e_plugin
+  l2e.api
+  l2e_api.c
+  l2e.c
+)

src/plugins/lacp/CMakeLists.txt

@@ -0,0 +1,32 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(lacp_plugin
+  lacp.api
+  lacp.c
+  lacp_api.c
+  selection.c
+  rx_machine.c
+  tx_machine.c
+  mux_machine.c
+  ptx_machine.c
+  cli.c
+  input.c
+  node.c
+)
+
+add_vpp_api_test_plugin(lacp_test_plugin
+  lacp.api
+  lacp_test.c
+)
+

src/plugins/lb/CMakeLists.txt

@@ -0,0 +1,27 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(lb_plugin
+  lb.api
+  api.c
+  cli.c
+  lb.c
+  node.c
+  util.c
+)
+
+add_vpp_api_test_plugin(lb_test_plugin
+  lb.api
+  lb_test.c
+)
+

src/plugins/mactime/CMakeLists.txt

@@ -0,0 +1,24 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(mactime_plugin
+  mactime.api
+  mactime.c
+  node.c
+)
+
+add_vpp_api_test_plugin(mactime_test_plugin
+  mactime.api
+  mactime_test.c
+)
+

src/plugins/map/CMakeLists.txt

@@ -0,0 +1,23 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(map_plugin
+  map.api
+  ip4_map.c
+  ip4_map_t.c
+  ip6_map.c
+  ip6_map_t.c
+  map_api.c
+  map.c
+  map_dpo.c
+)

src/plugins/marvell/CMakeLists.txt

@@ -0,0 +1,32 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+message("-- Looking for Marvell musdk")
+find_path(MUSDK_INCLUDE_DIR NAMES marvell/pp2/pp2.h)
+find_library(MUSDK_LIB NAMES musdk)
+
+if(MUSDK_INCLUDE_DIR AND MUSDK_LIB)
+  add_vpp_plugin(marvell_plugin
+    marvell.api
+    plugin.c
+    pp2/cli.c
+    pp2/format.c
+    pp2/input.c
+    pp2/output.c
+    pp2/pp2.c
+  )
+  include_directories(${MUSDK_INCLUDE_DIR})
+  message("-- Looking for Marvell musdk - found")
+else()
+  message("-- Looking for Marvell musdk - not found - marvell_plugin disabled")
+endif()

src/plugins/memif/CMakeLists.txt

@@ -0,0 +1,27 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(memif_plugin
+  memif.api
+  memif.c
+  memif_api.c
+  cli.c
+  node.c
+  device.c
+  socket.c
+)
+
+vpp_library_set_multiarch_sources(memif_plugin
+  device.c
+  node.c
+)

src/plugins/nat/CMakeLists.txt

@@ -0,0 +1,41 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(nat_plugin
+  nat.api
+  nat.c
+  nat_api.c
+  in2out.c
+  out2in.c
+  nat_ipfix_logging.c
+  nat_det.c
+  nat_reass.c
+  nat_dpo.c
+  nat44_cli.c
+  nat64.c
+  nat64_cli.c
+  nat64_in2out.c
+  nat64_out2in.c
+  nat64_db.c
+  dslite_dpo.c
+  dslite.c
+  dslite_in2out.c
+  dslite_out2in.c
+  dslite_cli.c
+  dslite_ce_encap.c
+  dslite_ce_decap.c
+  nat66.c
+  nat66_cli.c
+  nat66_in2out.c
+  nat66_out2in.c
+)

src/plugins/pppoe/CMakeLists.txt

@@ -0,0 +1,27 @@
+# Copyright (c) 2018 Cisco and/or its affiliates.
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at:
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+add_vpp_plugin(pppoe_plugin
+  pppoe.api
+  pppoe_api.c
+  pppoe.c
+  pppoe_cp.c
+  pppoe_cp_node.c
+  pppoe_decap.c
+)
+
+add_vpp_api_test_plugin(pppoe_test_plugin
+  pppoe.api
+  pppoe_test.c
+)
+